Haz videojuegos en español

importar "juego"

juego.abrir("Sprites", 640, 480)

# Un sprite dibujado con texto: cada letra es un color
sea lince = juego.sprite([
    "n....n",
    "nnnnnn",
    "nbnnbn",
    "nnnnnn"
], {"n": "#e8892b", "b": "#ffffff"})

sea fondo = juego.imagen("fondo.png")    # PNG, JPG o BMP
sea salto = juego.sonido("salto.wav")
juego.musica("tema.ogg")                   # en bucle, leída poco a poco

sea x = 320
mientras juego.abierto() {
    x = x + juego.eje("izq_x") * 200 * juego.dt()   # mando
    si juego.tecla_pulsada("espacio") { juego.reproducir(salto) }

    juego.dibujar(fondo, 0, 0)
    juego.dibujar(lince, x, 300, {"escala": 6, "espejo": x < 320})
    juego.presentar()
}

# Variables y tipos
sea  nombre = "Ana"
fijo PI     = 3.14159
sea lista notas = [9, 7, 10]

# Función con valor por defecto
funcion saludar(val texto nombre, val texto saludo = "Hola"): texto {
    devolver saludo + ", " + nombre
}

escribir(saludar("Mundo"))           # Hola, Mundo
escribir(saludar("Lince", "Bienvenido")) # Bienvenido, Lince

# Bucles
para cada numero n en rango(5) {
    escribir(n)
}

# Closures
funcion multiplicador(val numero factor): funcion {
    devolver funcion(val numero x): numero { devolver x * factor }
}
sea doble = multiplicador(2)
escribir(doble(5))   # 10

interfaz Forma {
    funcion area(): numero
    funcion describir(): texto
}

clase Rectangulo implementa Forma {
    funcion crear(val numero ancho, val numero alto): nulo {
        mi.ancho = ancho
        mi.alto  = alto
    }
    funcion area(): numero  { devolver mi.ancho * mi.alto }
    funcion describir(): texto {
        devolver "Rectángulo " + mi.ancho + "x" + mi.alto
    }
}

clase Cuadrado extiende Rectangulo {
    funcion crear(val numero lado): nulo {
        padre(lado, lado)   # llama al constructor del padre
    }
}

sea c = Cuadrado(5)
escribir(c.area())        # 25
escribir(c.describir())   # Rectángulo 5x5

# Generadores — secuencias perezosas
generador pares(val numero hasta): numero {
    para cada numero n en rango(hasta) {
        si n % 2 == 0 { producir n }
    }
}

para cada numero n en pares(10) {
    escribir(n)   # 0, 2, 4, 6, 8
}

# Fibonacci infinito (evaluación perezosa)
generador fibonacci(): numero {
    sea a = 0
    sea b = 1
    mientras verdadero {
        producir a
        sea tmp = a + b
        a = b
        b = tmp
    }
}

sea gen = fibonacci()
para cada numero _ en rango(8) {
    escribir(gen.siguiente())   # 0 1 1 2 3 5 8 13
}

# Manejo de errores estructurado
intentar {
    sea datos = json.parsear(archivos.leer("config.json"))
    escribir(datos["version"])
} capturar (ErrorRango e) {
    escribir("Clave no encontrada: " + e.mensaje)
} capturar (ErrorIO e) {
    escribir("No se pudo leer el archivo: " + e.mensaje)
} capturar (error e) {
    escribir("Error inesperado: " + e.mensaje)
} finalmente {
    escribir("Fin del proceso")
}

# Tipos de error nativos:
# error, ErrorTipo, ErrorRango, ErrorIO
# ErrorDivision, ErrorValor